Puppet Class: ores
- Defined in:
- puppet/modules/ores/manifests/init.pp
Overview
Class: ores
This role installs the [ORES] service.
Parameters
- deploy_dir
-
Path where ORES should be installed (example: '/vagrant/srv/ores').
- vhost_name
-
Hostname of the ORES server (example: 'ores.local.wmftest.net').
- port
-
Port used by the ORES server (only visible inside the virtual machine).
15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 |
# File 'puppet/modules/ores/manifests/init.pp', line 15
class ores (
$deploy_dir,
$vhost_name,
$port,
) {
include ::apache
include ::apache::mod::proxy
include ::apache::mod::proxy_http
include ::apache::mod::headers
require ::virtualenv
# revscoring
require_package('python3-dev', 'g++', 'gfortran', 'liblapack-dev', 'libopenblas-dev', 'libenchant-dev')
file { $deploy_dir:
ensure => directory,
}
# ORES (in a venv as it needs Python 3)
$venv_dir = "${deploy_dir}/venv"
virtualenv::environment { $venv_dir:
ensure => present,
owner => $::share_owner,
group => $::share_group,
python => 'python3',
require => [
Package['python3-dev', 'g++', 'gfortran', 'liblapack-dev', 'libopenblas-dev', 'libenchant-dev'],
File[$deploy_dir],
],
}
$sources_dir = "${deploy_dir}/src"
file { $sources_dir:
ensure => directory,
}
git::clone { 'revscoring':
directory => "${sources_dir}/revscoring",
remote => 'https://github.com/wikimedia/revscoring',
require => File[$sources_dir],
}
$ores_root = "${sources_dir}/ores"
git::clone { 'ores':
directory => $ores_root,
remote => 'https://github.com/wikimedia/ores',
require => File[$sources_dir],
}
virtualenv::package { 'revscoring':
package => "${sources_dir}/revscoring",
path => $venv_dir,
editable => true,
require => Git::Clone['revscoring'],
}
virtualenv::package { 'ores':
# Tricky syntax to get pip to install ores with the extra "redis"
# dependencies specified in setup.py
package => "${ores_root}[redis]",
path => $venv_dir,
editable => true,
require => [
Virtualenv::Package['revscoring'],
Git::Clone['ores'],
],
}
apache::reverse_proxy { 'ores':
port => $port,
}
$cfg_file = "${ores_root}/config/999-vagrant.yaml"
file { $cfg_file:
ensure => present,
content => template('ores/ores.yaml.erb'),
require => Git::Clone['ores'],
}
$logging_config = "${ores_root}/logging_config.yaml"
file { $logging_config:
ensure => present,
content => template('ores/logging.yaml.erb'),
require => Virtualenv::Package['ores'],
}
systemd::service { 'ores-wsgi':
ensure => present,
service_params => {
require => [
Virtualenv::Package['ores'],
Class['mediawiki::ready_service'],
Apache::Site['ores'],
],
subscribe => [
File[$cfg_file],
File[$logging_config],
],
},
}
systemd::service { 'ores-celery':
ensure => present,
service_params => {
require => [
Virtualenv::Package['ores'],
Class['mediawiki::ready_service'],
Apache::Site['ores'],
],
subscribe => [
File[$cfg_file],
File[$logging_config],
],
},
}
}
|