Puppet Class: etherpad

Defined in:
modules/etherpad/manifests/init.pp

Overview

SPDX-License-Identifier: Apache-2.0 Install and manage Etherpad Lite wikitech.wikimedia.org/wiki/Etherpad.wikimedia.org

Parameters:

  • etherpad_db_user (String)
  • etherpad_db_host (Stdlib::Fqdn)
  • etherpad_db_name (String)
  • etherpad_db_pass (String)
  • etherpad_ip (Stdlib::IP::Address) (defaults to: '0.0.0.0')
  • etherpad_port (Stdlib::Port) (defaults to: 9001)
  • service_ensure (Stdlib::Ensure::Service) (defaults to: 'running') 


4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
# File 'modules/etherpad/manifests/init.pp', line 4

class etherpad(
    String $etherpad_db_user,
    Stdlib::Fqdn $etherpad_db_host,
    String $etherpad_db_name,
    String $etherpad_db_pass,
    Stdlib::IP::Address $etherpad_ip        = '0.0.0.0',
    Stdlib::Port $etherpad_port             = 9001,
    Stdlib::Ensure::Service $service_ensure = 'running',
){
    ensure_packages('etherpad-lite')

    service { 'etherpad-lite':
        ensure    => $service_ensure,
        enable    => true,
        subscribe => File['/etc/etherpad-lite/settings.json'],
    }

    $ensure_auto_restarts = $service_ensure ? {
        running => 'present',
        default => 'absent',
    }

    profile::auto_restarts::service { 'etherpad-lite':
        ensure => $ensure_auto_restarts,
    }

    file { '/etc/etherpad-lite/settings.json':
        content => template('etherpad/settings.json.erb'),
    }

    file { '/usr/share/etherpad-lite/src/static/robots.txt':
        ensure => present,
        owner  => 'root',
        group  => 'root',
        mode   => '0444',
        source => 'puppet:///modules/etherpad/etherpad-robots.txt',
    }
}