Puppet Class: openstack::keystone::monitor::services

Defined in:
modules/openstack/manifests/keystone/monitor/services.pp

Overview

Parameters:

  • active (Any)
  • auth_port (Any)
  • public_port (Any)
  • critical (Any) (defaults to: false)
  • contact_groups (Any) (defaults to: 'wmcs-bots,admins')


4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# File 'modules/openstack/manifests/keystone/monitor/services.pp', line 4

class openstack::keystone::monitor::services(
    $active,
    $auth_port,
    $public_port,
    $critical=false,
    $contact_groups='wmcs-bots,admins',
    ) {

    # monitoring::service doesn't take a bool
    if $active {
        $ensure = 'present'
    }
    else {
        $ensure = 'absent'
    }
    $vhost = $::site ? {
        'codfw' => 'openstack.codfw1dev.wikimediacloud.org',
        default => 'openstack.eqiad1.wikimediacloud.org',
    }

    [$auth_port, $public_port].each |$port| {
        monitoring::service {
            default:
                ensure        => $ensure,
                critical      => $critical,
                contact_group => $contact_groups,
                notes_url     => 'https://wikitech.wikimedia.org/wiki/Portal:Cloud_VPS/Admin/Troubleshooting';
            "keystone-http-${port}":
                description   => "keystone endpoint port ${port}",
                check_command => "check_https_on_port!${port}";
            "keystone-http-${port}-ssl-expiry":
                description   => "keystone endpoint port ${port} SSL Expiry",
                check_command => "check_https_expiry!${vhost}!${port}";
        }
    }
}