Puppet Class: openstack::trove::service::victoria

Defined in:
modules/openstack/manifests/trove/service/victoria.pp

Overview

Parameters:

  • openstack_controllers (Array[Stdlib::Fqdn])
  • workers (Integer)
  • db_user (String)
  • db_pass (String)
  • db_name (String)
  • db_host (Stdlib::Fqdn)
  • ldap_user_pass (String)
  • keystone_admin_uri (String)
  • keystone_internal_uri (String)
  • region (String)
  • api_bind_port (Stdlib::Port)
  • rabbit_user (String)
  • rabbit_pass (String)
  • trove_guest_rabbit_user (String)
  • trove_guest_rabbit_pass (String)
  • trove_service_user_pass (String)
  • trove_service_project (String)
  • trove_service_user (String)
  • trove_quay_user (String)
  • trove_quay_pass (String)
  • designate_internal_uri (String)
  • trove_dns_zone (String)
  • trove_dns_zone_id (String)


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
# File 'modules/openstack/manifests/trove/service/victoria.pp', line 1

class openstack::trove::service::victoria(
    Array[Stdlib::Fqdn] $openstack_controllers,
    Integer             $workers,
    String              $db_user,
    String              $db_pass,
    String              $db_name,
    Stdlib::Fqdn        $db_host,
    String              $ldap_user_pass,
    String              $keystone_admin_uri,
    String              $keystone_internal_uri,
    String              $region,
    Stdlib::Port        $api_bind_port,
    String              $rabbit_user,
    String              $rabbit_pass,
    String              $trove_guest_rabbit_user,
    String              $trove_guest_rabbit_pass,
    String              $trove_service_user_pass,
    String              $trove_service_project,
    String              $trove_service_user,
    String              $trove_quay_user,
    String              $trove_quay_pass,
    String              $designate_internal_uri,
    String              $trove_dns_zone,
    String              $trove_dns_zone_id,
) {
    require "openstack::serverpackages::victoria::${::lsbdistcodename}"

    package { ['python3-trove', 'trove-common', 'trove-api', 'trove-taskmanager', 'trove-conductor']:
        ensure => 'present',
    }

    file {
        '/etc/trove/trove.conf':
            content   => template('openstack/victoria/trove/trove.conf.erb'),
            owner     => 'trove',
            group     => 'trove',
            mode      => '0440',
            show_diff => false,
            notify    => Service['trove-api', 'trove-taskmanager', 'trove-conductor'],
            require   => Package['trove-api'];
        '/etc/trove/trove-guestagent.conf':
            content   => template('openstack/victoria/trove/trove-guestagent.conf.erb'),
            owner     => 'trove',
            group     => 'trove',
            mode      => '0440',
            show_diff => false,
            notify    => Service['trove-api', 'trove-taskmanager', 'trove-conductor'],
            require   => Package['trove-api'];
        '/etc/trove/policy.yaml':
            source  => 'puppet:///modules/openstack/victoria/trove/policy.yaml',
            owner   => 'trove',
            group   => 'trove',
            mode    => '0644',
            notify  => Service['trove-api', 'trove-taskmanager', 'trove-conductor'],
            require => Package['trove-api'];
        '/etc/trove/api-paste.ini':
            source  => 'puppet:///modules/openstack/victoria/trove/api-paste.ini',
            owner   => 'trove',
            group   => 'trove',
            mode    => '0644',
            notify  => Service['trove-api'],
            require => Package['trove-api'];
        # This file is not used as far as I know, but the bullseye/victoria package post-install
        #  fails if it is not present.
        '/usr/share/trove-common/api-paste.ini':
            source => 'puppet:///modules/openstack/victoria/trove/api-paste.ini',
            owner  => 'trove',
            group  => 'trove',
            mode   => '0644';
        '/usr/lib/python3/dist-packages/trove/taskmanager/models.py':
            source  => 'puppet:///modules/openstack/victoria/trove/hacks/taskmanager/models.py',
            owner   => 'root',
            group   => 'root',
            mode    => '0644',
            notify  => Service['trove-api'],
            require => Package['trove-api'];
        '/usr/lib/python3/dist-packages/trove/instance/models.py':
            source  => 'puppet:///modules/openstack/victoria/trove/hacks/instance/models.py',
            owner   => 'root',
            group   => 'root',
            mode    => '0644',
            notify  => Service['trove-api'],
            require => Package['trove-api'];
    }
}