Puppet Class: profile::docker::reporter

Defined in:
modules/profile/manifests/docker/reporter.pp

Overview

This profile installs docker-report, and runs the report with the required frequency.

Parameters:

  • proxy (String) (defaults to: lookup('http_proxy'))
  • generate_reports (Boolean) (defaults to: lookup('profile::docker::reporter::generate_reports')) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
# File 'modules/profile/manifests/docker/reporter.pp', line 2

class profile::docker::reporter(
    String $proxy = lookup('http_proxy'),
    Boolean $generate_reports = lookup('profile::docker::reporter::generate_reports'),
) {
    package { 'python3-docker-report':
        ensure => present,
    }
    $report_ensure = $generate_reports ? {
        true => 'present',
        default => 'absent',
    }
    profile::docker::reporter::report {
        default:
            ensure => $report_ensure,
            proxy  => $proxy,
            ;
        # Report on base images and production-images
        'base':
            frequency => 'daily',
            ;
        # Report on releng images
        'releng':
            frequency => 'weekly',
            ;
        # Report on images used in production on k8s
        'k8s':
            frequency => 'weekly',
            ;
    }
}