Puppet Class: profile::druid::middlemanager

Defined in:
modules/profile/manifests/druid/middlemanager.pp

Overview

SPDX-License-Identifier: Apache-2.0 Class: profile::druid::middlemanager

Parameters:

  • properties (Hash[String, Any]) (defaults to: lookup('profile::druid::middlemanager::properties', {'default_value' => {}}))
  • env (Hash[String, String]) (defaults to: lookup('profile::druid::middlemanager::env', {'default_value' => {}}))
  • daemon_autoreload (Boolean) (defaults to: lookup('profile::druid::daemons_autoreload', {'default_value' => true}))
  • firewall_access (Optional[Array[String]]) (defaults to: lookup('profile::druid::firewall_access'))
  • monitoring_enabled (Boolean) (defaults to: lookup('profile::druid::middlemanager::monitoring_enabled', {'default_value' => false})) 


4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
 
# File 'modules/profile/manifests/druid/middlemanager.pp', line 4

class profile::druid::middlemanager(
    Hash[String, Any] $properties            = lookup('profile::druid::middlemanager::properties', {'default_value' => {}}),
    Hash[String, String] $env                = lookup('profile::druid::middlemanager::env', {'default_value' => {}}),
    Boolean $daemon_autoreload               = lookup('profile::druid::daemons_autoreload', {'default_value' => true}),
    Optional[Array[String]] $firewall_access = lookup('profile::druid::firewall_access'),
    Boolean $monitoring_enabled              = lookup('profile::druid::middlemanager::monitoring_enabled', {'default_value' => false}),
) {

    require ::profile::druid::common

    # If monitoring is enabled, then include the monitoring profile and set $java_opts
    # for exposing the Prometheus JMX Exporter in the Druid Broker process.
    if $monitoring_enabled {
        require ::profile::druid::monitoring::middlemanager
        $java_opts = $::profile::druid::monitoring::middlemanager::java_opts

        if $env['DRUID_EXTRA_JVM_OPTS'] {
            $monitoring_env_vars = {
                'DRUID_EXTRA_JVM_OPTS' => "${env['DRUID_EXTRA_JVM_OPTS']} ${java_opts}"
            }
        } else {
            $monitoring_env_vars = {
                'DRUID_EXTRA_JVM_OPTS' => $java_opts
            }
        }
    } else {
        $monitoring_env_vars = {}
    }

    $class_prefix = 'org.apache.druid'

    # Druid middlemanager Service
    class { '::druid::middlemanager':
        properties       => $properties,
        env              => merge($env, $monitoring_env_vars),
        should_subscribe => $daemon_autoreload,
        logger_prefix    => $class_prefix,
    }

    # Allow incoming connections to druid.indexer.runner.startPort + 900
    $peon_start_port = $::druid::middlemanager::runtime_properties['druid.indexer.runner.startPort']
    $peon_end_port   = $::druid::middlemanager::runtime_properties['druid.indexer.runner.startPort'] + 900
    firewall::service { 'druid-middlemanager':
        proto    => 'tcp',
        port     => $::druid::middlemanager::runtime_properties['druid.port'],
        src_sets => $firewall_access,
    }

    firewall::service { 'druid-middlemanager-indexer-task':
        proto      => 'tcp',
        port_range => [$peon_start_port, $peon_end_port],
        src_sets   => $firewall_access,
    }

    if $monitoring_enabled {
        # Special case for the middlemanager daemon: its correspondent Java
        # process name is 'middleManager'
        nrpe::monitor_service { 'druid-middlemanager':
            description  => 'Druid middlemanager',
            nrpe_command => "/usr/lib/nagios/plugins/check_procs -c 1:1 -C java -a \'${class_prefix}.cli.Main server middleManager\'",
            critical     => false,
            notes_url    => 'https://wikitech.wikimedia.org/wiki/Analytics/Systems/Druid',
        }
    }
}