Puppet Class: profile::kubernetes::node::dse_k8s

Defined in:
modules/profile/manifests/kubernetes/node/dse_k8s.pp

Summary

This profile is used to make OS-level changes on dse-k8s workers

Overview

SPDX-License-Identifier: Apache-2.0 Whether or not to set readahead for OpenSearch pod RBDs (block devices), ref T419041

Parameters:

  • set_rbd_readahead (Boolean) (defaults to: lookup('profile::kubernetes::node::dse_k8s::set_rbd_readahead', { default_value => false }))


7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# File 'modules/profile/manifests/kubernetes/node/dse_k8s.pp', line 7

class profile::kubernetes::node::dse_k8s (
    Boolean $set_rbd_readahead = lookup('profile::kubernetes::node::dse_k8s::set_rbd_readahead', { default_value => false }),
) {
    # Runs lvmd on workers that offer local storage via TopoLVM (T429325)
    include profile::kubernetes::node::lvmd

    # Creates the volume groups in lvm::volume_groups, if any. lvmd fails
    # to start if its volume group does not exist yet.
    class { 'lvm': }
    Class['lvm'] -> Class['profile::kubernetes::node::lvmd']

    # See: https://docs.opensearch.org/2.19/install-and-configure/install-opensearch/index/#important-settings
    # also note that Trixie and newer sets to `1048576`, and the recommended value of `262144` is insufficient
    # in our other OpenSearch clusters.
    sysctl::parameters { 'opensearch':
        values => {
            'vm.max_map_count' => 1048576,
        }
    }

    $set_rbd_cmd    = '/usr/local/sbin/set-rbd-readahead.py'
    $rbd_ensure     = $set_rbd_readahead ? { true => 'present', default => 'absent' }
    $rbd_file_ensure = $set_rbd_readahead ? { true => 'file', default => 'absent' }

    file { $set_rbd_cmd:
        ensure => $rbd_file_ensure,
        source => 'puppet:///modules/profile/kubernetes/node/dse_k8s/set-rbd-readahead.py',
        mode   => '0755',
    }

    systemd::timer::job { 'set-rbd-readahead':
        ensure            => $rbd_ensure,
        description       => 'Set readahead for OpenSearch pod RBDs (block devices)',
        command           => $set_rbd_cmd,
        user              => 'root',
        interval          => { 'start' => 'OnCalendar', 'interval' => '*:0/5' }, # every 5 minutes
        syslog_force_stop => false,
        require           => File[$set_rbd_cmd],
    }
}