Puppet Class: profile::memcached::instance

Defined in:
modules/profile/manifests/memcached/instance.pp

Overview

localcacert

Location of ca.pem Default: undef

*notls_port

By default, when we `enable_tls`, the host will listen `port` for TLS connections. By defining a `notls_port`, we have the ability to listen for unencrypted connections to a different port. Default: undef

firewall_srange

By default no firewall port is opened. This allows to grant access to an array of hosts

firewall_src_sets

By default no firewall port is opened. This allows to grant access to an array of firewall sets (e.g. DOMAIN_NETWORKS)

Parameters:

  • version (String) (defaults to: lookup('profile::memcached::version'))
  • port (Stdlib::Port) (defaults to: lookup('profile::memcached::port'))
  • size (Integer) (defaults to: lookup('profile::memcached::size'))
  • extended_options (Array[String]) (defaults to: lookup('profile::memcached::extended_options'))
  • max_seq_reqs (Integer) (defaults to: lookup('profile::memcached::max_seq_reqs'))
  • min_slab_size (Integer) (defaults to: lookup('profile::memcached::min_slab_size'))
  • growth_factor (Float) (defaults to: lookup('profile::memcached::growth_factor'))
  • memcached_user (String) (defaults to: lookup('profile::memcached::memcached_user'))
  • performance_cpu_governor (Optional[Boolean]) (defaults to: lookup('profile::memcached::performance_cpu_governor'))
  • extstore_ensure (Optional[WMFlib::Ensure]) (defaults to: lookup('profile::memcached::extstore_ensure'))
  • extstore_size (Optional[Integer]) (defaults to: lookup('profile::memcached::extstore_size'))
  • extstore_path (Optional[Stdlib::Unixpath]) (defaults to: lookup('profile::memcached::extstore_path'))
  • enable_tls (Optional[Boolean]) (defaults to: lookup('profile::memcached::enable_tls'))
  • notls_port (Optional[Stdlib::Port]) (defaults to: lookup('profile::memcached::notls_port'))
  • ssl_cert (Optional[Stdlib::Unixpath]) (defaults to: lookup('profile::memcached::ssl_cert'))
  • ssl_key (Optional[Stdlib::Unixpath]) (defaults to: lookup('profile::memcached::ssl_key'))
  • localcacert (Optional[Stdlib::Unixpath]) (defaults to: lookup('profile::memcached::localcacert'))
  • threads (Optional[Integer]) (defaults to: lookup('profile::memcached::threads'))
  • firewall_src_sets (Optional[Array[String[1]]]) (defaults to: lookup('profile::memcached::firewall_src_sets', { 'default_value' => undef }))
  • firewall_srange (Optional[Firewall::Range]) (defaults to: lookup('profile::memcached::firewall_srange', { 'default_value' => undef })) 


93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
 
# File 'modules/profile/manifests/memcached/instance.pp', line 93

class profile::memcached::instance (
    String                     $version                 = lookup('profile::memcached::version'),
    Stdlib::Port               $port                     = lookup('profile::memcached::port'),
    Integer                    $size                     = lookup('profile::memcached::size'),
    Array[String]              $extended_options         = lookup('profile::memcached::extended_options'),
    Integer                    $max_seq_reqs             = lookup('profile::memcached::max_seq_reqs'),
    Integer                    $min_slab_size            = lookup('profile::memcached::min_slab_size'),
    Float                      $growth_factor            = lookup('profile::memcached::growth_factor'),
    String                     $memcached_user           = lookup('profile::memcached::memcached_user'),
    Optional[Boolean]          $performance_cpu_governor = lookup('profile::memcached::performance_cpu_governor'),
    Optional[WMFlib::Ensure]   $extstore_ensure          = lookup('profile::memcached::extstore_ensure'),
    Optional[Integer]          $extstore_size            = lookup('profile::memcached::extstore_size'),
    Optional[Stdlib::Unixpath] $extstore_path            = lookup('profile::memcached::extstore_path'),
    Optional[Boolean]          $enable_tls               = lookup('profile::memcached::enable_tls'),
    Optional[Stdlib::Port]     $notls_port               = lookup('profile::memcached::notls_port'),
    Optional[Stdlib::Unixpath] $ssl_cert                 = lookup('profile::memcached::ssl_cert'),
    Optional[Stdlib::Unixpath] $ssl_key                  = lookup('profile::memcached::ssl_key'),
    Optional[Stdlib::Unixpath] $localcacert              = lookup('profile::memcached::localcacert'),
    Optional[Integer]          $threads                  = lookup('profile::memcached::threads'),
    Optional[Array[String[1]]] $firewall_src_sets        = lookup('profile::memcached::firewall_src_sets', { 'default_value' => undef }),
    Optional[Firewall::Range]  $firewall_srange          = lookup('profile::memcached::firewall_srange', { 'default_value' => undef }),
) {
    include ::profile::prometheus::memcached_exporter
    if $performance_cpu_governor {
        class { 'cpufrequtils': }
    }

    $extstore = $extstore_ensure ? {
        present => ["ext_path=${extstore_path}/datafile:${extstore_size}G"],
        default => [],
    }

    $base_extra_options = {
        '-o' => join($extended_options+$extstore, ','),
        '-D' => ':',
    }

    if $max_seq_reqs {
        $max_seq_reqs_opt = {'-R' => $max_seq_reqs}
    } else {
        $max_seq_reqs_opt = {}
    }

    if $threads {
        $threads_opt = {'-t' => $threads}
    } else {
        $threads_opt = {}
    }


    $extra_options = $base_extra_options + $max_seq_reqs_opt + $threads_opt

    class { '::memcached':
        size            => $size,
        port            => $port,
        version         => $version,
        growth_factor   => $growth_factor,
        min_slab_size   => $min_slab_size,
        extra_options   => $extra_options,
        memcached_user  => $memcached_user,
        enable_tls      => $enable_tls,
        notls_port      => $notls_port,
        ssl_cert        => $ssl_cert,
        ssl_key         => $ssl_key,
        localcacert     => $localcacert,
        extstore_ensure => $extstore_ensure,
        extstore_path   => $extstore_path,

    }

    if $firewall_src_sets {
        firewall::service { 'memcached':
            proto    => 'tcp',
            port     => $port,
            src_sets => $firewall_src_sets,
        }
    }

    if $firewall_srange {
        firewall::service { 'memcached':
            proto  => 'tcp',
            port   => $port,
            srange => $firewall_srange,
        }
    }

    if $notls_port and $enable_tls {
        if $firewall_src_sets {
            firewall::service { 'memcached_notls':
                proto    => 'tcp',
                port     => $notls_port,
                src_sets => $firewall_src_sets,
            }
        }

        if $firewall_srange {
            firewall::service { 'memcached_notls':
                proto  => 'tcp',
                port   => $notls_port,
                srange => $firewall_srange,
            }
        }
    }
}