Puppet Class: profile::phabricator::monitoring

Defined in:
modules/profile/manifests/phabricator/monitoring.pp

Overview

SPDX-License-Identifier: Apache-2.0

Class: profile::phabricator::monitoring

Parameters:

  • active_server (Stdlib::Fqdn) (defaults to: lookup('phabricator_active_server')) 


4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
 
# File 'modules/profile/manifests/phabricator/monitoring.pp', line 4

class profile::phabricator::monitoring (
    Stdlib::Fqdn $active_server = lookup('phabricator_active_server'),
){

    $phab_contact_groups = 'admins,phabricator'

    # https monitoring is on the virtual host 'phabricator'.
    # It should not be duplicated.
    if $::fqdn == $active_server {
        prometheus::blackbox::check::http { 'phabricator.wikimedia.org':
            severity    => 'page',
            alert_after => '5m',
            timeout     => '6s',
        }

        # dedicated check with collab team and severity task
        # Reporting to a phab task might not work if phabricator is down
        prometheus::blackbox::check::http { 'phabricator.wikimedia.org-collab':
            server_name        => 'phabricator.wikimedia.org',
            team               => 'collaboration-services',
            severity           => 'task',
            path               => '/',
            force_tls          => true,
            port               => 443,
            ip_families        => [ip4],
            timeout            => '6s',
            body_regex_matches => ['Welcome to Wikimedia Phabricator'],
        }

        nrpe::monitor_service { 'check_phab_phd':
            description   => 'PHD should be running',
            nrpe_command  => "/usr/lib/nagios/plugins/check_procs -c 1: --ereg-argument-array  'php ./phd-daemon' -u phd",
            contact_group => $phab_contact_groups,
            notes_url     => 'https://wikitech.wikimedia.org/wiki/Phabricator',
        }
    }

    prometheus::blackbox::check::tcp { 'phabricator-smtp':
        team     => 'collaboration-services',
        severity => 'task',
        port     => 25,
    }

}