Puppet Class: profile::puppetserver::git

Defined in:
modules/profile/manifests/puppetserver/git.pp

Summary

configuyre git repos

Overview

SPDX-License-Identifier: Apache-2.0

Parameters:

  • ensure (Wmflib::Ensure) (defaults to: lookup('profile::puppetserver::git::ensure')) —

    ensurable parameter

  • basedir (Stdlib::Unixpath) (defaults to: lookup('profile::puppetserver::git::basedir')) —

    the git repo base dir

  • user (String[1]) (defaults to: lookup('profile::puppetserver::git::user')) —

    the owner of the git repo

  • group (String[1]) (defaults to: lookup('profile::puppetserver::git::group')) —

    the group owner of the git repo

  • control_repo (String[1]) (defaults to: lookup('profile::puppetserver::git::control_repo')) —

    the name of the main puppet control repo

  • repos (Hash[String, Hash]) (defaults to: lookup('profile::puppetserver::git::repos')) —

    addtional repos to configure

  • code_dir (Stdlib::Unixpath) (defaults to: lookup('profile::puppetserver::code_dir')) 


9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
 
# File 'modules/profile/manifests/puppetserver/git.pp', line 9

class profile::puppetserver::git (
    Wmflib::Ensure      $ensure             = lookup('profile::puppetserver::git::ensure'),
    Stdlib::Unixpath    $basedir            = lookup('profile::puppetserver::git::basedir'),
    String[1]           $user               = lookup('profile::puppetserver::git::user'),
    String[1]           $group              = lookup('profile::puppetserver::git::group'),
    String[1]           $control_repo       = lookup('profile::puppetserver::git::control_repo'),
    Hash[String, Hash]  $repos              = lookup('profile::puppetserver::git::repos'),
    Stdlib::Unixpath    $code_dir           = lookup('profile::puppetserver::code_dir'),
) {
    $servers = (wmflib::role::hosts('puppetmaster::frontend') +
                wmflib::role::hosts('puppetmaster::backend') +
                wmflib::role::hosts('puppetserver')).sort.unique
    unless $repos.has_key($control_repo) {
        fail("\$control_repo (${control_repo}) must be defined in \$repos")
    }

    $control_repo_dir = "${basedir}/${control_repo}"
    $home_dir = "/home/${user}"

    systemd::sysuser { $user:
        home_dir => $home_dir,
        shell    => '/bin/sh',
    }
    file { $home_dir:
        ensure  => directory,
        owner   => $user,
        group   => $user,
        mode    => '0755',
        require => Systemd::Sysuser[$user],
    }
    # TODO: refactor this so its closer to the g10k code
    # This is required to run g10k as root
    sudo::user { $user:
        privileges => [
            'ALL = NOPASSWD: /usr/local/bin/puppetserver-deploy-code',
        ],
    }

    file {"${home_dir}/.ssh":
        ensure => directory,
        owner  => $user,
        group  => $group,
        mode   => '0700',
    }
    file {
        default:
            ensure    => file,
            owner     => $user,
            group     => $group,
            mode      => '0400',
            show_diff => false;
        "${home_dir}/.ssh/id_rsa":
            content   => secret('ssh/gitpuppet/gitpuppet.key');
        "${home_dir}/.ssh/gitpuppet-private-repo":
            content   => secret('ssh/gitpuppet/gitpuppet-private.key');
    }
    ssh::userkey { $user:
        content => template('profile/puppetserver/git/gitpuppet_authorized_keys.erb'),
    }

    unless $servers.empty() {
        ferm::service { 'open access for puppetservers':
            proto  => 'tcp',
            port   => 22,
            srange => $servers,
        }
    }

    wmflib::dir::mkdir_p([$basedir.dirname, $basedir], {
        owner  => $user,
        group  => $group
    })

    $repos.each |$repo, $config| {
        $dir = "${basedir}/${repo}"

        git::systemconfig { "mark puppet repo ${dir} as safe":
            ensure   => absent,
            settings => {},
        }

        $origin = $config['origin'].lest || { "https://gerrit.wikimedia.org/r/${repo}" }
        ensure_resource('file', $dir.dirname, {
            ensure => stdlib::ensure($ensure, 'directory'),
            owner  => $user,
            group  => $group,
        })
        if $config['init'] {
            file { $dir:
                ensure => directory,
                owner  => $user,
                group  => $group,
            }
            exec { "git init ${dir}":
                command => '/usr/bin/git init',
                user    => $user,
                group   => $group,
                cwd     => $dir,
                creates => "${dir}/.git",
                require => File[$dir],
            }
            $git_require = Exec["git init ${dir}"]
        } else {
            git::clone { $repo:
                ensure    => $ensure,
                directory => $dir,
                branch    => $config['branch'],
                origin    => $origin,
                owner     => $user,
                group     => $group,
                require   => File[$dir.dirname],
                before    => Service['puppetserver'],
            }
            $git_require = Git::Clone[$repo]
        }
        if $config.has_key('hooks') {
            $hooks_dir = "${dir}/.git/hooks"
            $config['hooks'].each |$hook, $source| {
                $content = $source.stdlib::start_with('puppet:///modules/') ? {
                    true    => {'source' => $source},
                    default => {'content' => template($source)},
                }
                file { "${hooks_dir}/${hook}":
                    ensure  => stdlib::ensure($ensure, 'file'),
                    owner   => $user,
                    group   => $group,
                    mode    => '0550',
                    require => $git_require,
                    *       => $content,
                }
            }
        }
        if $config.has_key('link') {
            file { $config['link']:
                ensure  => stdlib::ensure($ensure, 'link'),
                target  => $dir,
                force   => true,
                before  => Service['puppetserver'],
                require => $git_require,
            }
        }
        if $config.has_key('config') {
            $content = $config['config'].stdlib::start_with('puppet:///modules/') ? {
                true    => {'source' => $config['config']},
                default => {'content' => template($config['config'])},
            }
            file { "${dir}/.git/config":
                ensure  => stdlib::ensure($ensure, 'file'),
                owner   => $user,
                group   => $group,
                require => $git_require,
                *       => $content,
            }
        }
    }

    exec { 'puppetserver-deploy-code':
        command   => '/usr/local/bin/puppetserver-deploy-code',
        creates   => "${code_dir}/environments/production",
        notify    => Service['puppetserver'],
        require   => [Package['g10k'], File['/usr/local/bin/puppetserver-deploy-code']],
        subscribe => [Git::Clone[$control_repo], File[$puppetserver::g10k::config_file]],
    }

    file { '/usr/local/bin/pgit':
        ensure  => file,
        content => "#!/bin/sh\nexec sudo -u ${user} git \"$@\"\n",
        mode    => '0555',
    }

    git::config { "${home_dir}/.gitconfig":
        settings => {
            'user' => {
                'name'  => $user,
                'email' => "${user}@${facts['networking']['fqdn']}",
            },
        },
    }
}