Puppet Class: profile::wmcs::etcd

Defined in:
modules/profile/manifests/wmcs/etcd.pp

Overview

SPDX-License-Identifier: Apache-2.0

Parameters:

  • peer_hosts (Array[Stdlib::Fqdn]) (defaults to: lookup('profile::wmcs::etcd::peer_hosts'))
  • backup_hosts (Array[Stdlib::Fqdn]) (defaults to: lookup('profile::wmcs::etcd::backup_hosts', {default_value => []}))
  • bootstrap (Boolean) (defaults to: lookup('profile::wmcs::etcd::cluster_bootstrap', {default_value => false}))
  • latency_ms (Integer) (defaults to: lookup('profile::wmcs::etcd::latency_ms', {default_value => 10}))
  • snapshot_count (Integer) (defaults to: lookup('profile::wmcs::etcd::snapshot_count', {default_value => 10000}))
  • adv_client_port (Stdlib::Port) (defaults to: lookup('profile::wmcs::etcd::adv_client_port', {default_value => 2379}))
  • enable_v2 (Boolean) (defaults to: lookup('profile::wmcs::etcd::enable_v2', {default_value => false}))


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
# File 'modules/profile/manifests/wmcs/etcd.pp', line 2

class profile::wmcs::etcd (
    Array[Stdlib::Fqdn] $peer_hosts      = lookup('profile::wmcs::etcd::peer_hosts'),
    Array[Stdlib::Fqdn] $backup_hosts    = lookup('profile::wmcs::etcd::backup_hosts', {default_value => []}),
    Boolean             $bootstrap       = lookup('profile::wmcs::etcd::cluster_bootstrap', {default_value => false}),
    Integer             $latency_ms      = lookup('profile::wmcs::etcd::latency_ms', {default_value => 10}),
    Integer             $snapshot_count  = lookup('profile::wmcs::etcd::snapshot_count', {default_value => 10000}),
    Stdlib::Port        $adv_client_port = lookup('profile::wmcs::etcd::adv_client_port', {default_value => 2379}),
    Boolean             $enable_v2       = lookup('profile::wmcs::etcd::enable_v2', {default_value => false}),
) {
    if $bootstrap {
        $cluster_state = 'new'
    } else {
        $cluster_state = 'existing'
    }

    # for $peers_list we need a string like this:
    # node1=https://node1.project.eqiad1.wikimedia.cloud:2380,node2=https://node2.project.eqiad1.wikimedia.cloud:2380,...
    $protocol    = 'https://'
    $port        = ':2380'
    $peers_list_array = map($peer_hosts) |$element| {
        $value = "${element}=${protocol}${element}${port}"
    }
    $peers_list = join(($peers_list_array), ',')

    # the certificate trick
    $etcd_cert_pub    = "/etc/etcd/ssl/${facts['networking']['fqdn']}.pem"
    $etcd_cert_priv   = "/etc/etcd/ssl/${facts['networking']['fqdn']}.priv"
    $etcd_cert_ca     = '/etc/etcd/ssl/ca.pem'
    $puppet_cert_pub  = $facts['puppet_config']['hostcert']
    $puppet_cert_priv = $facts['puppet_config']['hostprivkey']
    $puppet_cert_ca   = profile::base::certificates::get_trusted_ca_path()

    file { ['/etc/etcd/', '/etc/etcd/ssl/']:
        ensure => directory,
    }

    file { $etcd_cert_pub:
        ensure  => present,
        source  => "file://${puppet_cert_pub}",
        owner   => 'etcd',
        group   => 'etcd',
        notify  => Service['etcd'],
        require => Package['etcd-server'],
    }

    file { $etcd_cert_priv:
        ensure    => present,
        source    => "file://${puppet_cert_priv}",
        owner     => 'etcd',
        group     => 'etcd',
        mode      => '0640',
        show_diff => false,
        notify    => Service['etcd'],
        require   => Package['etcd-server'],
    }

    file { $etcd_cert_ca:
        ensure  => present,
        source  => "file://${puppet_cert_ca}",
        owner   => 'etcd',
        group   => 'etcd',
        notify  => Service['etcd'],
        require => Package['etcd-server'],
    }

    class { '::etcd::v3':
        member_name      => $facts['networking']['fqdn'],
        cluster_state    => $cluster_state,
        max_latency_ms   => $latency_ms,
        snapshot_count   => $snapshot_count,
        peers_list       => $peers_list,
        adv_client_port  => $adv_client_port,
        client_cert      => $etcd_cert_pub,
        client_key       => $etcd_cert_priv,
        trusted_ca       => $etcd_cert_ca,
        peer_cert        => $etcd_cert_pub,
        peer_key         => $etcd_cert_priv,
        use_client_certs => true,
        enable_v2        => $enable_v2,
    }

    # restart the etcd service if a cert file changes
    File[$etcd_cert_pub]  ~> Service[etcd]
    File[$etcd_cert_priv] ~> Service[etcd]
    File[$etcd_cert_ca]   ~> Service[etcd]

    firewall::service { 'etcd_peers':
        proto  => 'tcp',
        port   => [2379, 2380],
        srange => $peer_hosts,
    }

    unless $backup_hosts.empty() {
        firewall::service { 'etcd_backups':
            proto  => 'tcp',
            port   => 2379,
            srange => $backup_hosts,
        }
    }

    #
    # this is for metrics collections. The etcd server requires client certs
    # to fetch metrics. We have a nginx proxy to hide the TLS details from the
    # prometheus client.
    #
    $exposed_port = 9051
    nginx::site { 'expose_etcd_metrics':
        content => template('profile/wmcs/etcd/etcd_expose_metrics.nginx.erb'),
    }

    # restart the nginx service if a cert file changes
    File[$etcd_cert_pub]  ~> Service[nginx]
    File[$etcd_cert_priv] ~> Service[nginx]
    File[$etcd_cert_ca]   ~> Service[nginx]
}