Puppet Class: statsite

Defined in:
modules/statsite/manifests/init.pp

Overview

Parameters:

  • ensure (Wmflib::Ensure) (defaults to: present)


23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
# File 'modules/statsite/manifests/init.pp', line 23

class statsite (
  Wmflib::Ensure $ensure = present,
) {
    package { 'statsite':
        ensure => $ensure,
    }

    file { '/etc/statsite':
        ensure => ensure_directory($ensure),
        force  => true,
        owner  => 'root',
        group  => 'root',
        mode   => '0555',
    }

    # stop the default service and rely on statsite::instance to do the
    # right thing
    exec { 'mask_statsite':
        command => '/bin/systemctl mask statsite.service',
        creates => '/etc/systemd/system/statsite.service',
        before  => Package['statsite'],
    }

    systemd::unit { 'statsite@':
        ensure  => $ensure,
        restart => true,
        content => systemd_template('statsite@')
    }

    systemd::unit { 'statsite-instances':
        ensure  => $ensure,
        restart => true,
        content => systemd_template('statsite-instances')
    }

    rsyslog::conf { 'statsite':
        ensure   => $ensure,
        source   => 'puppet:///modules/statsite/rsyslog.conf',
        priority => 20,
    }
}