Defined Type: wikistats::job::update

Defined in:
modules/wikistats/manifests/job/update.pp

Overview

SPDX-License-Identifier: Apache-2.0 a timer (job) to update a wikistats table

Parameters:

  • project (String) (defaults to: $name)
  • hour (Integer) (defaults to: 0)
  • minute (Integer) (defaults to: 0)
  • day (Optional[String]) (defaults to: undef)
  • ensure (Wmflib::Ensure) (defaults to: 'present') 


3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
# File 'modules/wikistats/manifests/job/update.pp', line 3

define wikistats::job::update (
    String $project = $name,
    Integer $hour = 0,
    Integer $minute = 0,
    Optional[String] $day = undef,
    Wmflib::Ensure $ensure = 'present',
){

    $minute_extinfo=$minute+30;

    if $day {
      $interval = "${day} *-*-* ${hour}:${minute}:00"
      $interval_extinfo = "${day} *-*-* ${hour}:${minute_extinfo}:00"
    } else {
      $interval = "*-*-* ${hour}:${minute}:00"
      $interval_extinfo = "*-*-* ${hour}:${minute_extinfo}:00"
    }

    systemd::timer::job { "wikistats-update-${name}":
        ensure          => $ensure,
        user            => 'wikistatsuser',
        description     => "pull fresh numbers for table ${name}",
        command         => "/usr/bin/php /usr/lib/wikistats/update.php ${project}",
        logging_enabled => true,
        logfile_basedir => '/var/log/wikistats/',
        logfile_name    => "update-${name}.log",
        interval        => {'start' => 'OnCalendar', 'interval' => $interval},
    }

    systemd::timer::job { "wikistats-extinfo-update-${name}":
        ensure          => $ensure,
        user            => 'wikistatsuser',
        description     => "pull extended info for table ${name}",
        command         => "/usr/bin/php /usr/lib/wikistats/update.php ${project} extinfo",
        logging_enabled => true,
        logfile_basedir => '/var/log/wikistats/',
        logfile_name    => "update-extinfo-${name}.log",
        interval        => {'start' => 'OnCalendar', 'interval' => $interval_extinfo},
    }
}